CS 5363: Programming Languages and Compilers

The University of Texas at San Antonio
Fall Semester, 2009

Compiler Project, The TL09 Language Syntax

Lexical Elements

All TL09 lexical elements (a.k.a. tokens) are separated by spaces and should match one of the categories below.

If the definition of a lexical element is in quotes, then it is meant to match exactly, the contained string. Otherwise, it is a regular expression. Square brackets in regular expressions are used as an abbreviation for matching ranges of letters. For example, [0-9] matches any digit, and [a-zA-Z] matches any English letter in capital or lower case.

Numbers, Literals, and Identifiers:

• num = (-|ε)[1-9][0-9]*|0
• boollit = FALSE|TRUE
• ident = [a-z][a-z0-9]*

Symbols and Operators:

• LP = "("
• RP = ")"
• ASGN = ":="
• SC = ";"
• OP2 = "*" | "/" | "%"
• OP3 = "+" | "-"
• OP4 = "==" | "!=" | "<" | ">" | "<=" | ">="

Keywords:

• IF = "IF"
• THEN = "THEN"
• ELSE = "ELSE"
• BEGIN = "BEGIN"
• END = "END"
• WHILE = "WHILE"
• DO = "DO"
• PROGRAM = "PROGRAM"
• VAR = "VAR"
• AS = "AS"
• INT = "INT"
• BOOL = "BOOL"

Built-in Procedures:

• WRITEINT = "WRITEINT"
• READINT = "READINT"

BNF Grammar

<program> ::= PROGRAM ident <declarations> BEGIN <statementSequence> END

<declarations> ::= VAR ident AS <type> SC <declarations>
               | ε

<type> ::= INT | BOOL

<statementSequence> ::= <statement> SC <statementSequence>
                    | ε

<statement> ::= <assignment>
            | <ifStatement>
            | <whileStatement>
            | <writeInt>

<assignment> ::= ident ASGN <expression>
             | ident ASGN READINT

<ifStatement> ::= IF <expression> THEN <statementSequence> <elseClause> END

<elseClause> ::= ELSE <statementSequence>
             | ε

<whileStatement> ::= WHILE <expression> DO <statementSequence> END

<writeInt> ::= WRITEINT <expression>

<expression> ::= <simpleExpression>
             | <simpleExpression> OP4 <simpleExpression>

<simpleExpression> ::= <term> OP3 <term>
                   | <term>

<term> ::= <factor> OP2 <factor>
       | <factor>

<factor> ::= ident
         | num
         | boollit
         | LP <expression> RP

Errata/Clarifications

• 2009/09/15: Noted that, as was mentioned in the language overview, the lexical elements are space-seperated.
• 2009/09/15: Removed some superfluous parentheses from regular expressions. The meaning is unchanged since the rules of precedence say the same thing as the removed parentheses.